Балка со свободными концами

[AndreyR 1]

Всем доброго времени суток! Скажите пожалуйста, возможно ли в ANSYS провести расчет балки со свободными концами, нагруженной поперечной нагрузкой?

[Fedor 1 602]

Если балка симметричная то без проблем, эта задача эквивалентна половине балки с заделкой по концам :)

[AndreyR 1]

Спасибо, Fedor. Но не могли бы Вы пояснить более подробно свой ответ. Балка в задаче круглого сечения, переменного по длине. Вы имеете в виду симметричность относительно плоскости (вертикальной и горизонтальной)? Или подскажите где это можно прочитать, если не сложно))

[Fedor 1 602]

Обычно в любом приличном учебнике сопромата есть. Можете в хелпах Ansys посмотреть. Просто условия симметрии позволяют доопределить перемещения, которые нужны для равновесия тела, иначе оно будет лететь с ускорением как Ньютон прописал в своих законах. С точки зрения деформаций, которые являются производными любые константы для перемещений годятся, так как уходят при дифференцировании для вычисления интеграла упругой энергии :)

"относительно плоскости (вертикальной и горизонтальной)? " - а это зависит от того как балка сориентирована. При зеркальном отражении ничего не должно меняться, или кососимметрично.

<noindex> Тут </noindex> и другие варианты симметрий, их много разных :)

[Борман 2 380]

AndreyR

да вы лучше нарисуйте на бумажке вашу схему, а мы посмотрим..

А то нам препод еще в универе говорил, что "жесткой заделки не бывает", а я вот использую на свой страх и риск.

[Fedor 1 602]

Мне в пятом классе говорили, что и прямых линий не бывает и даже точек

А вот вожусь с интегрированием в путях и понял как найти интересуемые параметры в произвольной точке. Путь нулевой длины и все дела :)

/POST1

! Получить напряжение в произвольной точке пространства

x=60437 $ y=11000 $ z=0 ! глобальные координаты точки

path,my ,2,5,1 ! минимальный набор информации для объекта путь

ppath,1,,x,y,z $ ppath,2,,x,y,z ! описать путь как точку

pdef,res,s,1 $ *get,myout,path,,last,res ! взять значение в переменную myout

Интересный вопрос : как строится путь в цилиндрической системе координат по двум точкам и начале координат. Получается похожий на окружность, но расстояния от точек до центра разные...

Примерно так строится с переменным радиусом, что за геометрическая фигура получится :

! создание локальной системы координат цилиндрической и установить как активную

n=12 $ xc=52452 $ yc=30703 $ LOCAL,n,CYLIN,xc,yc,0,,,,,, $ CSYS,n,

PATH,my2,2,,,

xs=50000 $ ys=11000 $ zs=0 $ PPATH,1,,xs,ys,zs,n, ! стартовая точка пути

xp=35437 $ yp=20000 $ zp=0 $ PPATH,2,,xp,yp,zp,n, ! конечная точка пути

! взять тензор напряжений на точки пути

PDEF,sx,S,X,AVG $ PDEF,sy,S,Y,AVG $ PDEF,sz,S,Z,AVG

PDEF,sxy,S,XY,AVG $ PDEF,syz,S,YZ,AVG $ PDEF,sxz,S,XZ,AVG

! взять данные в таблицу TRACDATA

PAGET,TRACDATA,TABL

[Влад. 6]

В хелпе ANSYS в закладке Search набираешь BEAM и жмешь поиск

смотришь вывод начинающийся на VM - всевозможные варианты расчета балок.

[AndreyR 1]

Всем доброго времени суток. Опишу свою задачу подробнее.

Имеется длинное обтекаемое осесимметричное тело, совершающее полет на большой скорости под некоторым углом атаки.

Решаю эту задачу во Флюенте, получаю распределение давления по корпусу и все остальные интересующие меня параметры. Далее необходимо представить это тело в виде балки, на которую накладывается распределенная нагрузка переменная по длине балки и по времени.

Проблема заключается в том, что тело находится в полете.

Как это смоделировать в Ансисе? Подскажите пожалуйста.

Как задать переменную нагрузку по длине и по времени. В хелпе нашел только задание линейно изменяющейся нагрузки.

[Влад. 6]

Можно через таблицу одновременно задать зависимость от времени и от координаты.

*DIM,lo,table,2,2,,Time,x

*SET,LO(0,1,1) , 5 ! 1ая координата Х

*SET,LO(0,2,1) , 10 ! 2ая Х

*SET,LO(1,0,1) , 1 ! 1 секунда

*SET,LO(1,1,1) , 5

*SET,LO(1,2,1) , 6

*SET,LO(2,0,1) , 2 ! 2 секунда

*SET,LO(2,1,1) , 8

*SET,LO(2,2,1) , 9

[AndreyR 1]

Спасибо, Влад.

А как эти значения наложить на балку?

[Влад. 6]

Открываешь всезнающий ансисовский хелп и набираешь в нем имя своего балочного элемента, типа BEAM189

Он тебе даст его характеристики и возможные нагрузки. Общая команда для нагрузок по балкам SFBeAM.

Если влом переводить с английского библиотеку элементов, то у Басова есть по ним гнижка.

[AndreyR 1]

К сожалению, задание нагрузки на балку через таблицу не идет. Проходит только команда SFBEAM, но нагрузку надо задавать на каждый элемент- на его начало и конец, то есть нагрузка линейно распределена по элементу. Но это ерунда, можно всю нелинейную нагрузку аппроксимировать линейными участками.

Как задать ее в зависимости от времени? Кто-нибудь знает?

[Влад. 6]

вот пример.

finish
/clear,start

/PREP7  
ET,1,BEAM188
SECTYPE,   1, BEAM, RECT, , 0   
SECOFFSET, CENT 
SECDATA,10,10,10,10,0,0,0,0,0,0 

K,1,,,, 
K,2,50,,,   
LSTR,1,2  

MPTEMP,,,,,,,,  
MPTEMP,1,0  
MPDATA,EX,1,,20000  
MPDATA,PRXY,1,,0.3  
MPDATA,DENS,1,,7e-10
MPDATA,DAMP,1,,.2   

ESIZE,2,0,  
LMESH,All  

D,1,,,,,,ALL

*dim,pre,table,10,3,,time,x 

*SET,PRE(0,1) , 0 	! x coordinates
*SET,PRE(0,2) , 25
*SET,PRE(0,3) , 50

*SET,PRE(1,0) , 1 	! 1st second
*SET,PRE(1,1) , 1 	! pressure at x=0
*SET,PRE(1,2) , 2 	! pressure at x=25
*SET,PRE(1,3) , 1 	! pressure at x=50

*SET,PRE(2,0) , 2 	! 2nd second
*SET,PRE(2,1) , 2 	! pressure ...
*SET,PRE(2,2) , 1 
*SET,PRE(2,3) , 2 

*SET,PRE(3,0) , 3 
*SET,PRE(3,1) , 3 
*SET,PRE(3,2) , 2 
*SET,PRE(3,3) , 3 

*SET,PRE(4,0) , 4 
*SET,PRE(4,1) , 1 
*SET,PRE(4,2) , 2 
*SET,PRE(4,3) , 1 

*SET,PRE(5,0) , 5 
*SET,PRE(5,1) , 2 
*SET,PRE(5,2) , 2 
*SET,PRE(5,3) , 2 

*SET,PRE(6,0) , 6 
*SET,PRE(6,1) , 3 
*SET,PRE(6,2) , 3 
*SET,PRE(6,3) , 3 

*SET,PRE(7,0) , 7 
*SET,PRE(7,1) , 4 
*SET,PRE(7,2) , 1 
*SET,PRE(7,3) , 3 

*SET,PRE(8,0) , 8 
*SET,PRE(8,1) , 1 
*SET,PRE(8,2) , 2 
*SET,PRE(8,3) , 3 

*SET,PRE(9,0) , 9 
*SET,PRE(9,1) , 3 
*SET,PRE(9,2) , 5 
*SET,PRE(9,3) , 4 

*SET,PRE(10,0) , 10   
*SET,PRE(10,1) , 2
*SET,PRE(10,2) , 3
*SET,PRE(10,3) , 1

/solu

*do,i,1,10	! go for time

PARSAV,all,'1','txt'

*if,i,EQ,1,THEN
ANTYPE,trans
*elseif,i,GT,1,THEN
ANTYPE,,rest,last
*endif

PARRES,NEW,'1','txt'

NLGEOM,	off
TRNOPT,	FULL 
EQSLV,	PCG                      
NROPT,	FULL,,ON
NEQIT,	500
CNVTOL,	U,,0.001
CNVTOL,	F,,0.001,,0.01
AUTOTS,	Off
KBC,0 
OUTRES,ALL,ALL 
NSUBST,5,0,0   
TiME,i

*get,ecnt,elem,0,count	! the count of elements	
*do,k,1,ecnt						! apply pressure
*get,in,elem,k,node,1	
*get,inX,node,in,loc,x
*get,jn,elem,k,node,2
*get,jnX,node,jn,loc,x
sfbeam,k,2,Press,Pre(i,inX),Pre(i,jnX), , , , ,0
*enddo

/PSF,PRES,NORM,1,0,1
EPLOT 
/wait,1

SOLVE

*enddo

/post1
/EFACET,1   
PLNS,U,SUM  
ANTIME,50,0.5E-01, ,1,2,0,10

[AndreyR 1]

Еще раз спасибо, Влад.