Данные в деталь из внешнего файла

[alek77 222]

Добрый день!

 

Можно ли каким образом прописать тестовые данные в свойства детали или сборки из внешнего источника, текстовика или таблицы EXEL?

Как пример: цена покупной детали, прописанная в таблице EXEL.

Может быть через уравнения или еще как?

Буду благодарен за любую подсказку.

[Kelny 1 314]

1 час назад, alek77 сказал:

свойства детали или сборки из внешнего источника, текстовика или таблицы EXEL?

Вероятно ТАБЛИЦА ПАРАМЕТРОВ: http://help.solidworks.com/SearchEx.aspx?q=таблица+параметров&sort=&version=2010&lang=Russian&prod=SolidWorks

[Солнцеворот 207]

Можно при помощи макроса.

[Kelny 1 314]

31 минуту назад, Солнцеворот сказал:

Можно при помощи макроса.

С макросом думать надо.

Тогда уж возможно для каких-то задач TabBuilder: http://help.solidworks.com/2010/russian/solidworks/oh_propertytabbuilder/allcontent/solidworks/noncore/propertytabbuilder/c_property_tab_builder_overview.html

[VOleg 228]

Макрос записывает из открытого файла Эксель в свойства открытого файла Солида. В нем лично мои наворотики - если не нужны удалите. В конце Эксель закрывается.

Sub xls2prop()
 Dim swModel As ModelDoc2
 Dim mde As SldWorks.ModelDocExtension
 Dim cpm As CustomPropertyManager
 Dim swConfigMgr As SldWorks.ConfigurationManager
 Dim swConfig As SldWorks.Configuration
 Dim swCustPropMgr As SldWorks.CustomPropertyManager
 Dim strName As String
 Dim vNames As Variant
 Dim xls As Object
 Dim wbk As Excel.Workbook
 Dim wsh As Excel.Worksheet
 Dim i As Integer, n As Integer, nov As Integer
 Dim psp As Boolean
 
 Set swApp = Application.SldWorks
 Set swModel = swApp.ActiveDoc

 ' Начальные проверки
 If swModel Is Nothing Then
    MsgBox "Ничего не открыто", , "Откройте деталь или сборку"
    Exit Sub
 End If
 i = swModel.GetType
 If i <> swDocPART And i <> swDocASSEMBLY Then
    MsgBox "Текущий документ д.б. деталью или сборкой!", , "Откройте деталь или сборку"
    Exit Sub
 End If
 psp = IIf(i = swDocPART And InStr(UCase(swModel.GetPathName), "СП^") > 0, True, False)
 
 On Error Resume Next
 Set xls = GetObject(, "Excel.Application")
 If Err Then
    Err.Clear
    On Error GoTo 0
    MsgBox "Не запущен Excel"
    Exit Sub
 End If
 On Error GoTo 0
 Set mde = swModel.Extension
 Set cpm = mde.CustomPropertyManager("")
 ' обозначение и наименование из текущей конфигурации
 Set swConfigMgr = swModel.ConfigurationManager
 Set swConfig = swConfigMgr.ActiveConfiguration
 Set swCustPropMgr = swConfig.CustomPropertyManager
 Set wbk = xls.ActiveWorkbook
 Set wsh = wbk.ActiveSheet
 n = wsh.UsedRange.Rows.Count
 nov = 0
 For i = 1 To 2
   strName = wsh.Cells(i, 1)
   nov = nov + swCustPropMgr.Set(strName, wsh.Cells(i, 3))
 Next i
 For i = 3 To n
   strName = wsh.Cells(i, 1)
   If psp And UCase(strName) = "РАЗДЕЛВ" Then
     If cpm.Set(strName, "8") < 0 Then
       cpm.Add2 strName, swCustomInfoText, "99"
       nov = nov + 1
     End If
   Else
     If cpm.Set(strName, wsh.Cells(i, 3)) < 0 Then
       cpm.Add2 strName, swCustomInfoText, wsh.Cells(i, 3)
       nov = nov + 1
     End If
   End If
 Next i
 xls.DisplayAlerts = False
 xls.Quit
 Set xls = Nothing
 Set wbk = Nothing
 MsgBox "Записано" + Str(n) + " свойств, из них" + Str(nov) + " новых"
End Sub

[Maik812 302]

Прекрасно прописываешь параметры и создаешь сразу шаблон на них . По этим данным можно еще переименовывать/добовлять в имя, сортировать и раскрашивать имена файлов.