Балка с заделками.

[Hulget 0]

Собственно как в ансис задать балку с заделками по краям, чтобы узнать собственные частоты и формы?Точнее даже, не как нарисовать саму балку, а через что найти эти формы и частоты?

[Chingachguk 4]

а через что найти эти формы и частоты?

Наверное через модальный анализ.

Для плоской задачи:

/prep7 !Входим в препроцессор
!*
!        Геометрические параметры
H=0.2   !Высота сечения
B=0.1   !Ширина сечения
L1=6     !Длина балки
!*
!        Задание свойств материала
UIMP,1,EX,DENS,NUXY,2e11,7800,0.3 ! Модуль Юнга, Плотность, Коэффициент Пуассона
!*
!        Задание типа элемента
ET,1,beam188  
!*
!        Блок задания констант элемента
SECTYPE,1,BEAM,RECT,1Beam188,0
SECOFFSET,CENT 
SECDATA,H,B,0,0,0,0,0,0,0,0,0,0 
!*
!        Задание ключевых точек
K,1,0,0,0
K,2,L1,0,0
!*
!        Построение линии
LSTR, 1,2
!
LESIZE,All,,,20,1 ! Всем линиям присвоить 20 делений на элементы
LMESH,All !Построить сетку на всех линиях
!       Задание условий закрепления
NSEL,All !Выделение всех узлов
D,All,,,,,,,,UZ,ROTX,ROTY,,
!       Задание опор
NSEL,S,LOC,X,0 !Выбор узла с координатами 0,0,0
NSEL,A,LOC,X,L1 !Выбор узла с координатами х=L1
D,All,,,,,,All,,,,,, !Закрепление выбранного узла
ALLSEL,ALL 
FINISH !Выход из препроцессора решения
!
/SOLU
ANTYPE, 2 !анализ на собственные частоты
MODOPT, SUBSP, 5 !спецификация метода решения
EQSLV, FRONT !тип решателя
MXPAND, 5,,,0 !записывать решение двух собственных частот
SOLVE
/POST 1
SET, FIRST !первая форма колебаний
PLDISP, 1
SET, LIST
!SET, NEXT !вторая и следующие формы колебаний
!PLDISP, 1 

[Hulget 0]

 

а через что найти эти формы и частоты?

Наверное через модальный анализ.

Для плоской задачи:

/prep7 !Входим в препроцессор
!*
!        Геометрические параметры
H=0.2   !Высота сечения
B=0.1   !Ширина сечения
L1=6     !Длина балки
!*
!        Задание свойств материала
UIMP,1,EX,DENS,NUXY,2e11,7800,0.3 ! Модуль Юнга, Плотность, Коэффициент Пуассона
!*
!        Задание типа элемента
ET,1,beam188  
!*
!        Блок задания констант элемента
SECTYPE,1,BEAM,RECT,1Beam188,0
SECOFFSET,CENT 
SECDATA,H,B,0,0,0,0,0,0,0,0,0,0 
!*
!        Задание ключевых точек
K,1,0,0,0
K,2,L1,0,0
!*
!        Построение линии
LSTR, 1,2
!
LESIZE,All,,,20,1 ! Всем линиям присвоить 20 делений на элементы
LMESH,All !Построить сетку на всех линиях
!       Задание условий закрепления
NSEL,All !Выделение всех узлов
D,All,,,,,,,,UZ,ROTX,ROTY,,
!       Задание опор
NSEL,S,LOC,X,0 !Выбор узла с координатами 0,0,0
NSEL,A,LOC,X,L1 !Выбор узла с координатами х=L1
D,All,,,,,,All,,,,,, !Закрепление выбранного узла
ALLSEL,ALL 
FINISH !Выход из препроцессора решения
!
/SOLU
ANTYPE, 2 !анализ на собственные частоты
MODOPT, SUBSP, 5 !спецификация метода решения
EQSLV, FRONT !тип решателя
MXPAND, 5,,,0 !записывать решение двух собственных частот
SOLVE
/POST 1
SET, FIRST !первая форма колебаний
PLDISP, 1
SET, LIST
!SET, NEXT !вторая и следующие формы колебаний
!PLDISP, 1 

Спасибо большое!