Округление массы

[Konstruktor77 0]

Здравствуйте, подскажите пожайлуста, как организовать округление массы изделия по следующему алгоритму:

1. для изделий с массой менее 100 кг - округлять массу в большую сторону до целого значения (например, если получается 86,23 кг, то масса принимается 87 кг);

2. для изделий с массой от 100 кг до 1000 кг - округлять массу в большую сторону до значения, кратного 5 (например, если получается 241,72 кг, то масса принимается 245 кг);

3. для изделий с массой более 1000 кг - округлять массу в большую сторону до значения, кратного 10 (например, если получается 1332,17 кг, то масса принимается 1340 кг).

[Ruslan 688]

Пример уравнения ( в модели):

IF PRO_MP_MASS<100

MASS=ceil(PRO_MP_MASS)

ENDIF

IF PRO_MP_MASS>=100 & PRO_MP_MASS<1000

MASS=5*ceil(PRO_MP_MASS/5)

ENDIF

IF PRO_MP_MASS>=1000

MASS=10*ceil(PRO_MP_MASS/10)

ENDIF

Если это нужно для чертежа, то лучше и правильнее эти условия написать в уравнениях региона основной надписи (естественно параметры будут немножко другие).

IF mdl_generic_PRO_MP_MASS<100

MASS=ceil(mdl_generic_PRO_MP_MASS)

ENDIF

IF mdl_generic_PRO_MP_MASS>=100 & mdl_generic_PRO_MP_MASS<1000

MASS=5*ceil(mdl_generic_PRO_MP_MASS/5)

ENDIF

IF mdl_generic_PRO_MP_MASS>=1000

MASS=10*ceil(mdl_generic_PRO_MP_MASS/10)

ENDIF

[Konstruktor77 0]

Спасибо большое Ruslan, это то что я хотел!

[wexus 43]

Делюсь своими уравнениями округления массы, вдруг кому пригодиться, или есть замечания.

Пользуюсь для отчётов в чертежах.

По умолчанию настройка отображения трех знаков после запятой "default_dec_places 3"

Что делают уравнения. Округляют значение по принципу выявления целой и дробной части и записи их в определённый формат, отличается тем что после запятой остаётся только необходимое количество символов.

Условия

Если значение меньше 1 то записать так как есть.

Например mdl_param_value = 0,089 тогда MASS = 0,089

Если значение больше или равно 1 но меньше 10 округляем до двух знаков после запятой.

Например mdl_param_value = 11,192 тогда MASS = 11,19.

Выявляем дробную часть:

Z100=11,192-floor(11,192)=0,192

Далее идёт проверка на значение дробной части:

Если дробная часть < 0,05 то MASSA будет равна только целой части, дробная часть слишком мала.

Если дробная часть => 0,05 но <= 0,1 то MASSA будет равна целая часть + 1

Если дробная часть > 0,1 то MASSA будет равна целая часть + дробная часть * 100

Если дробная часть = 0 (Значение изначально целочисленное) то MASSA будет равна целой части

Если значение больше или равно 10 но меньше 100 округляем до одного знака после запятой.

Если значение больше или равно 100 округляем до целого.

Сами уравнения:

/* Округление массы

IF mdl_param_value<1

MASSA=mdl_param_value

ENDIF



IF 1<=mdl_param_value & mdl_param_value<10

Z100=mdl_param_value-floor(mdl_param_value)

IF Z100 < 0.05

MASSA=itos(mdl_param_value)

ENDIF

IF 0.05 <= Z100 & Z100 <= 0.1

MASSA=itos(floor(mdl_param_value))+","+"1"

ENDIF

IF Z100 > 0.1

MASSA=itos(floor(mdl_param_value))+","+itos(z100*100)

ENDIF

IF Z100 == 0

MASSA=itos(mdl_param_value)

ENDIF

ENDIF



IF 10<=mdl_param_value & mdl_param_value<100

Z10=mdl_param_value-floor(mdl_param_value)

IF Z10 < 0.05

MASSA=itos(mdl_param_value)

ENDIF

IF 0.05 <= Z10 & Z10 <= 0.1

MASSA=itos(floor(mdl_param_value))+","+"1"

ENDIF

IF Z10 > 0.1

MASSA=itos(floor(mdl_param_value))+","+itos(z10*10)

ENDIF

IF Z10 == 0

MASSA=itos(mdl_param_value)

ENDIF

ENDIF



IF 100<=mdl_param_value

MASSA=itos(mdl_param_value)

ENDIF

[Sergey___1978 35]

А как у вас масса в граммах реализована в этих уравнениях?

Округления до 1 знака в принципе достаточно. Что-то у вас очень много уравнений.

У меня так:

IF MDL_GENERIC_PRO_MP_MASS > 1

МАССА=MDL_GENERIC_PRO_MP_MASS

GR=""

ENDIF

IF MDL_GENERIC_PRO_MP_MASS < 0.1

МАССА=MDL_GENERIC_PRO_MP_MASS*1000

GR=" г"

ENDIF

IF MDL_GENERIC_PRO_MP_MASS == 0

МАССА=MDL_GENERIC_PRO_MP_MASS

GR="Пересчитай массу"

ENDIF

IF (MDL_GENERIC_PRO_MP_MASS >= 0.1) & (MDL_GENERIC_PRO_MP_MASS < 1)

МАССА=MDL_GENERIC_PRO_MP_MASS

IF (MDL_GENERIC_PRO_MP_MASS*10-FLOOR(MDL_GENERIC_PRO_MP_MASS*10))>=0.5

МАССА=MDL_GENERIC_PRO_MP_MASS-0.1

ENDIF

GR=ITOS(MDL_GENERIC_PRO_MP_MASS*100)

GR=EXTRACT(GR,2,1)

ENDIF

[Jenny 3]

Добрый день. Подскажите, как в Creo в чертеже изменить единицы измерения массы. В моделе в кг, а в чертеже высвечиваются в г.

[davidovka 53]

Для начала покажите свою форматку.

[Jenny 3]

 

20 hours ago, davidovka said:

Для начала покажите свою форматку.

Что это значит?) 

[maxx2000 587]

3 часа назад, Jenny сказал:

Что это значит?)

ничего запрещённого

[Jenny 3]

2 hours ago, maxx2000 said:

ничего запрещённого

Ох сразу отлегло) 

Так по вопросу получается ответа не увидела) 

[maxx2000 587]

не знаешь что такое форматка в Крео?  Шаблон оформления документа

[Jenny 3]

23 hours ago, maxx2000 said:

не знаешь что такое форматка в Крео?  Шаблон оформления документа

Я поняла. Но не понимаю при чем тут шаблон оформления документа. Обычный чертеж для ескд. Все табличные данные заполнены. Но стандартно идет обозначение в кг. В общем уже разобралась с уравнениями в чертеже.