Вопрос По Kbe

[Z-MAN 0]

Есть код:

#! NX/KF 4.0



DefClass: Shatun_2 (ug_base_part);



(Any Parameter) cyrcle:; 

(Any Parameter) line1:; 

(Number Parameter) num: 2; 

(Number Parameter) Radius: 225; 

(Point Modifiable) ptn2: ug_curve_askPointOnCurve( cyrcle:,num: ); 

(Point Modifiable) ptn3: ug_curve_askPointOnCurve( line1:, nth(1,nth(1,ptn_intersection:)) ); 

(List Modifiable) ptn_intersection: ug_curve_askCurveIntersection( line1:, arc1:, 0.1 ); 

(Vector Modifiable) vector_x: ug_curve_askTangent( line2:, 0 ); 

(Vector Modifiable) vector_y: -perpendicular( vector_x: ); 



(Child) arc1: {

 Class, ug_arc; 

 Radius, Radius:; 

 center, ptn2:; 

 Layer, 6; 

}; 

(Child) line2: {

 Class, ug_line; 

 Start_Point, ptn2:; 

 End_Point, ptn3:; 

 Layer, 6; 

 demandOrder, {arc1:}; 

}; 



(Child) Shatun: {

 Class, ug_component; 

 File_Name, "D:\UG\shatun-asm.prt"; 

 Reference_Set_Name, "model"; 

 Component_Name, "SHATUN-ASM"; 

 Origin, ptn2:; 

 x_axis, vector(0,0,-1); 

 y_axis, vector_y:; 

 demandOrder, {line2:}; 

};

для работы необходимо, чтобы была окруджность и линия

я хочу вставить несколько таких моделей

а как сделать не получается

#! NX/KF 4.0



DefClass: Shatun (ug_base_part);

(any Parameter) cyrcle:;

(any Parameter) Line:;

(Number Parameter) radius: 225.0;

(Integer Parameter) num: 5;

(List Modifiable) lst1: ug_curve_askProperties( cyrcle: ); 

(Number Modifiable) end_ptn: nth(4,lst1:);

(Number modifiable) step: end_ptn:/num:;

(any) list1: loop

{

for $a from 0 to end_ptn: by step:;

for $str is ug_createInstance({Class, shatun_2,cyrcle, cyrcle:,line1, line:,radius, radius:,num, $a});

};

не работает ug_createInstance

Или подскажите, как лучше организовать цикл?

[niki 0]

#! NX/KF 4.0

DefClass: my_cool_lines (ug_base_part);

(Child List) multilines: {

Class, ug_line;

quantity, 5;

Start_Point, Point( 0, 0, child:index: * 10 );

End_Point, Point( 100, 0, child:index: * 10 );

};

[Z-MAN 0]

Ураа... Заработало!

#! NX/KF 4.0

DefClass: Shatun (ug_base_part);

(any Parameter) cyrcle:;

(any Parameter) Line:;

(Number Parameter) radius: 225.0;

(Integer Parameter) num: 5;

(List Modifiable) lst1: ug_curve_askProperties( cyrcle: );

(Number Modifiable) end_ptn: nth(4,lst1:);

(Number modifiable) step: end_ptn:/num:;

(Child List) shatun_x:{

Class, shatun_2,

Quantity, num:;

cyrcle, cyrcle:,

line1, line:,

radius, radius:,

num, step:*child:index:;

};