Переименование файлов сборки по "маске"

[Ectoplaza 12]

Собственно в вопросов два:

 

1. Необходимо переименовать каждую деталь входящую в общую сборку, добавив дату ревизии в конце имени файла.

2. Далее, имея в имени файла предыдущие число, месяц и год, сделать выборку и заменить числа актуальными на момент изменения/сохранения файла.

Есть ли в CATIA такая возможность?

 

p.s. PDM'ы не предлагать их нет у нас...

[lexincton 70]

Скриптами

[Ectoplaza 12]

@lexincton Написал скрипт, который рекурсивно обходит дерево, нумерует детали/сборки и обновляет дату ревизии документов входящих в сборку. Далее попытался сохранить измененные файлы под новыми именами, но получил ошибку. Не могу понять почему код не работает, строку с ошибкой закомментировал.

 

Reveal hidden contents  

Language = "VBSCRIPT"
Sub CATMain()
Set mainDocument = CATIA.ActiveDocument
Set rootAssembly = mainDocument.Product
sTmpPath = CATIA.ActiveDocument.Path
clrProp rootAssembly
setProp rootAssembly, 0, sTmpPath
clrProp rootAssembly
End Sub

Sub setProp(thisProduct, thisAsm, sTmpPath)
  Dim currAsm, currPrt
  currAsm = thisAsm
  currPrt = 0
  Set productList = thisProduct.Products
  setData thisProduct, currAsm, 0, "CADProduct", sTmpPath
  For i = 1 To productList.Count
    If (productList.Item(i).DescriptionRef <> "True" And _
        productList.Item(i).Revision <> "ANY") Then
      If (productList.Item(i).Products.Count > 0) Then
        currAsm = currAsm + 1
        setProp productList.Item(i), currAsm, sTmpPath
      Else
        currPrt = currPrt + 1
        setData productList.Item(i), thisAsm, currPrt, "CADPart", sTmpPath
      End If
    End If
  Next
End Sub

Sub setData(document, thisAsm, thisPrt, thisDfn, sTmpPath)
  document.PartNumber = "MP 2720 " & _
    String(2 - Len(thisAsm), "0") & thisAsm & _
    String(2 - Len(thisPrt), "0") & thisPrt
  document.Definition = "Definition"
  document.Revision = getDate()
  document.DescriptionRef = "True"

  'Error: Object doesn't support this property or method "document.SaveAs"
  'document.SaveAs(sTmpPath & "\" & document.PartNumber & " " & _
  'document.Definition & " " & document.Revision & "." & thisDfn)
End Sub

Function getDate()
  SetLocale "en-us"
  Dim currDay, currMonth, currYear, mark
  currDay = Day(Date)
  currMonth = Month(Date)
  currYear = Year(Date) Mod 100
  getDate = String(2 - Len(currDay), "0") & currDay & "." & _
         MonthName(currMonth,true) & "." & currYear
End Function

Sub clrProp (thisProduct)
  Set productList = thisProduct.Products
  For i = 1 To productList.Count
    productList.Item(i).DescriptionRef = ""
    clrProp productList.Item(i)
  Next
End Sub

Hide  

 

А вот код, что ниже  под спойлером, работает, т.е. сохраняет деталь под новым именем. Код простой, в нем нет проверки соответствия типу, работает только с ранее сохраненными деталями, но, тем не менее работает.

 

Reveal hidden contents  

Language = "VBSCRIPT"
Sub CATMain()
Set partDocument1 = CATIA.ActiveDocument
Set product1 = partDocument1.GetItem("PartName")

partDocument1.SaveAs(CATIA.ActiveDocument.Path & "\" & product1.PartNumber & " " & _
		     product1.Definition & " " & product1.Revision & ".CATPart")
End Sub

Hide  

 

Буду благодарен за любую помощь.

[lexincton 70]

Код пока не могу проверить. Может в имени недопустимые символы?

[Ectoplaza 12]

@lexincton Строку "document.SaveAs" заменил на "document.ReferenceProduct.Parent.SaveAs" и все заработало.

Правда я так и не понял что я сделал. Пока что в работе макроса много ограничений, но он работает.

 

Единственно что хотелось бы избавиться от этого сообщения, которое появляется для каждой сохраняемой детали.

 

Reveal hidden contents  

Hide  

[Martmath2 1]

Скрытый текст

'Language = "VBSCRIPT"
Sub CATMain()
CATIA.DisplayFileAlerts = False
Set mainDocument = CATIA.ActiveDocument
Set rootAssembly = mainDocument.Product
sTmpPath = CATIA.ActiveDocument.Path
clrProp rootAssembly
setProp rootAssembly, 0, sTmpPath
clrProp rootAssembly
CATIA.DisplayFileAlerts = True
End Sub

Sub setProp(thisProduct, thisAsm, sTmpPath)
  Dim currAsm, currPrt
  currAsm = thisAsm
  currPrt = 0
  Set productList = thisProduct.Products
  setData thisProduct, currAsm, 0, "CADProduct", sTmpPath
  For i = 1 To productList.Count
    If (productList.Item(i).DescriptionRef <> "True" And _
        productList.Item(i).Revision <> "ANY") Then
      If (productList.Item(i).Products.Count > 0) Then
        currAsm = currAsm + 1
        setProp productList.Item(i), currAsm, sTmpPath
      Else
        currPrt = currPrt + 1
        setData productList.Item(i), thisAsm, currPrt, "CADPart", sTmpPath
      End If
    End If
  Next
End Sub

Sub setData(document, thisAsm, thisPrt, thisDfn, sTmpPath)
  document.PartNumber = "MP 2720 " & _
    String(2 - Len(thisAsm), "0") & thisAsm & _
    String(2 - Len(thisPrt), "0") & thisPrt
  document.Definition = "Definition"
  document.Revision = getDate()
  document.DescriptionRef = "True"
  'Error: Object doesn't support this property or method "document.SaveAs"
  Dim dc As document
  Set dc = document.ReferenceProduct.Parent
  dc.SaveAs sTmpPath & "\" & document.PartNumber & " " & document.Definition & " " & document.Revision & "." & thisDfn
End Sub

Function getDate()
Dim codeString As String
Dim scriptControl As Object
Set scriptControl = CreateObject("MSScriptControl.ScriptControl")

codeString = "Sub getDateByLocale(locale)" & vbCrLf & "SetLocale locale" & vbCrLf & " End Sub"
With scriptControl
    .Language = "VBScript"
    .addCode codeString
    printDateByLocale = .Run("getDateByLocale", "en-us")
End With
  Dim currDay, currMonth, currYear, mark
  currDay = Day(Date)
  currMonth = Format(Date, "m") 'MonthName(Month(Now)) '
  
  currYear = Year(Date) Mod 100
  getDate = String(2 - Len(currDay), "0") & currDay & "." & _
         Format(Date, "m") & "." & currYear
End Function

Sub clrProp(thisProduct)
  Set productList = thisProduct.Products
  For i = 1 To productList.Count
    productList.Item(i).DescriptionRef = ""
    clrProp productList.Item(i)
  Next
End Sub

 

Ну зачем у продукта то сейв аз вызывать. Код в примере для VBA. Кстати после SetLocale месяц все равно русский (может на скрипте срабатывает, может неправильно вызываю - не уверен).

CATIA.DisplayFileAlerts = False

 возможно поможет

Изменено 9 ноября 2018 пользователем Martmath2

[Ectoplaza 12]

@Martmath2  Спасибо, это именно то что мне нужно было.

 

Тестовая сборка до применения макроса 

Hide  

 

Тестовая сборка после применения макроса  

Hide  

 

В планах добавить дополнительную проверку и обновлять дату ревизии только тем сборкам/деталям, в которые вносились правки. Правда пока не знаю как получить доступ к этому свойству. Предполагаю что должно быть какое-то свойство "Modified"  но пока не нашел.

[Martmath2 1]

Скрытый текст

Sub CATMain()
Dim productDocument1 As ProductDocument
Set productDocument1 = CATIA.ActiveDocument
Dim product1 As Product
Set product1 = productDocument1.Product
rtt = FileDateTime(product1.ReferenceProduct.Parent.FullName)
End Sub

 

Дату из файла сравнивать с тем что записал до этого, как вариант.

Цитата

Предполагаю что должно быть какое-то свойство "Modified"

нету.

[Тимо 0]

В 09.11.2018 в 18:12, Ectoplaza сказал:

@Martmath2  Спасибо, это именно то что мне нужно было.

 

Тестовая сборка до применения макроса 

Hide  

 

Тестовая сборка после применения макроса  

Hide  

 

В планах добавить дополнительную проверку и обновлять дату ревизии только тем сборкам/деталям, в которые вносились правки. Правда пока не знаю как получить доступ к этому свойству. Предполагаю что должно быть какое-то свойство "Modified"  но пока не нашел.

Всем привет. Итоговым вариантом макроса можете поделиться?