Обработка наклонных плоскостей в Heidenhain для "Чайников"

[Pavel_WR 2]

Уважаемые форумчане, приветствую и прошу помощи   Хочу разобраться вот с какой задачей...

Имеются заготовки, на которых необходимо произвести обработку на наклонной плоскости. У каждой заготовки угол наклона плоскости индивидуальный. Имеется станок Hermle с поворотным столом (А, С) и стойкой heidenhain.

Вопрос!
Каким образом можно автоматизировать вычисление необходимых углов поворота осей, чтоб ось инструмента находилась под прямым углом к обрабатываемой плоскости?
Хотелось бы получить практический совет от людей, решавших подобные задачи.
Какие циклы использовать для "ощупывания" плоскости заготовки? 431 или ещё какие варианты есть? Каким образом использовать данные полученных измерений и передавать их для поворота осей? Какие варианты поворота плоскостей вообще существуют? Знаю о существовании Хермлевого цикла 330 "Трехмерный поворот в основное положение". Если не использовать его, то каким образом поворачивать оси? Можно ли использовать PLANE SPATIAL или PLANE POINTS?

В этом вопросе я полный чайник, но очень хочется разобраться, и прежде чем пробовать что-то делать на станке, хотелось бы подстраховаться грамотными советами   
Спасибо!

[ben_laden 39]

Станка под рукой нет, да и давно я не пользовался подобным функционалом, по попробую пояснить.

Так понимаю, что отклонения углов в заготовках не очень большие и есть некий номинальный угол(ы), заданные на чертеже. В начале программы задаете разворот на номинальные углы (можно через PLANE SPATIAL, а можно и через PLANE POINTS - что больше нравится), затем вызываете цикл замера плоскости. Щуп замеряет плоскость и автоматом корректирует значения углов разворота (если циклы правильно заданы). После замера плоскости вызывается основная программа и... фрезеруете, сверлите, точите... 

Это все в теории, на практике вам бы помог пример реальной программы, но у меня таковой не имеется под руками. Покурите мануал на предмет работы с повернутой плоскостью обработки (функция PLANE и способы ее задания) и работы цикла 431. В сети хватает русско-язычных мануалов по Хайду, но ссылок я, к сожалению, не подскажу, а сюда грузить - слишком много весят.

[Pavel_WR 2]

Маны то я курю, но перед ваянием в станке я надеялся узреть здесь кусок готового кода с настроенными циклами 

[ben_laden 39]

... я надеялся узреть здесь кусок готового кода с настроенными циклами 

Понимаю. 

Как я уже сказал, с 3+2 не работаю уже довольно давно, да и конкретно ваш случай с плоскостью не попадался, но принцип везде одинковый, с любыми циклами touch probe.

Ниже кусок программы обработки и замера отверстия (смог найти в архиве только это). Разница с вашим случаем в том, что вы сначала меряете и корректируете, а потом обрабатываете.  Попробуйте по аналогии, не спешите, при отработке подачку на минимум и все получится.

0 BEGIN PGM OP100 MM 

1 BLK FORM 0.1 Z X-100 Y-100 Z+0

2 BLK FORM 0.2  X+100  Y+100  Z+40

3 CYCL DEF 247 NAZN.KOORD.BAZ.TOCH ~

    Q339=+1    ;NOMER TOCHKI ODN.

4 PLANE RESET TURN F10000

5 FUNCTION RESET TCPM

6 ; REAMER TOOL

7 TOOL CALL 23 Z S2000

8 M1

9 M3 M8

10 CYCL DEF 7.0 SMESCHENJE NULJA

11 CYCL DEF 7.1  X+0

12 CYCL DEF 7.2  Y+0

13 CYCL DEF 7.3  Z+0

14 PLANE SPATIAL SPA+0 SPB+90 SPC+0 TURN F10000

15 L  X-20.4  Y-49 F MAX M3 M8

16 L  Z+125

17 CYCL DEF 201 RAZWIORTYWANIE ~

    Q200=+2    ;RASSTO. BEZOPASNOSTI ~

    Q201=-8.4  ;GLUBINA ~

    Q206=+60   ;PODACHA NA GLUBINU ~

    Q211=+0    ;WYDER.WREMENI WNIZU ~

    Q208=+60   ;PODACHA WYCHODA ~

    Q203=+68.7 ;SURFACE COORDINATE ~

    Q204=+100  ;2-JE BEZOP.RASSTOJ.

18 L  X-20.4  Y-49 FMAX M99

19 L  Z+150 R0 FMAX M5 M9

20 ; TOUCH PROBE TOOL

21 TOOL CALL 33 Z S100

22 L  X-20.4  Y-49  Z+150 R0 FMAX

23 TCH PROBE 421 IZMERENIE OTWIERSTIA ~

    Q273=-20.4 ;1-AJA KOORD.CENTRA ~

    Q274=-49   ;2-JA KOORD.CENTRA ~

    Q262=+5    ;NOMINALNYJ DIAMETR ~

    Q325=+0    ;UGOL NACHAL.TOCHKI ~

    Q247=+90   ;SCHAG UGLA ~

    Q261=+67   ;WYSOTA IZMERENIA ~

    Q320=+1    ;RASSTO. BEZOPASNOSTI ~

    Q260=+150  ;B.WYSOTA? ~

    Q301=+1    ;DWISH.NA BEZ.WYSOTU ~

    Q275=+5.01 ;MAKSIMALNYJ RAZMER ~

    Q276=+5    ;MINIMALNYJ RAZMER ~

    Q279=+0.01 ;DOPUSK 1-J CENTR ~

    Q280=+0.01 ;DOPUSK 2-J CENTR ~

    Q281=+2    ;PROTOKOL IZMERENIA ~

    Q309=+1    ;PGM- STOP DOPUSK ~

    Q330=+32   ;INSTRUMENT ~

    Q423=+4    ;COMPENSATION ~

    Q365=+1    ;WID PEREMESCHENJA

24 L  Z+150 R0 FMAX 

25 ........

[aw75 0]

Вопрос решили?

Если нет, могу помочь, такое делали.

[Sergey1984 4]

Помогите мне решить такую проблему.

Не получается с плоскостями

[vatokompas 8]

@Sergey1984 Что именно не выходит?

[Sergey1984 4]

14 часа назад, vatokompas сказал:

@Sergey1984 Что именно не выходит?

Есть деталь ,нужно просвердить отверстия под углом 17градусов по кругу.на определенном расстоянии  друг от друга.но когда поворачию стол у меня не выходит нужно размера до центра этих отверстий.стойка  itnc530

Edited June 19, 2018 by Sergey1984

[vatokompas 8]

51 минуту назад, Sergey1984 сказал:

Есть деталь ,нужно просвердить отверстия под углом 17градусов по кругу.на определенном расстоянии  друг от друга.но когда поворачию стол у меня не выходит нужно размера до центра этих отверстий.стойка  itnc530

Используйте PLANE функцию.

 

53 минуты назад, Sergey1984 сказал:

Есть деталь ,нужно просвердить отверстия под углом 17градусов по кругу.на определенном расстоянии  друг от друга.но когда поворачию стол у меня не выходит нужно размера до центра этих отверстий.стойка  itnc530

Используйте PLANE функцию.

[Sergey1984 4]

3 часа назад, vatokompas сказал:

 

Используйте PLANE функцию.

Ну так использую.все поворачивает но растояние не сходится 

[vatokompas 8]

20 минут назад, Sergey1984 сказал:

Ну так использую.все поворачивает но растояние не сходится 

Можете скинуть прогу или эскиз где что не сходится?

Edited June 19, 2018 by vatokompas

[Sergey1984 4]

6 минут назад, vatokompas сказал:

Можете скинуть прогу или эскиз где что не сходится?

Сейчас на рисую

[Sergey1984 4]

36 минут назад, vatokompas сказал:

Можете скинуть прогу или эскиз где что не сходится?

пишет ошибку при загрузке файла.объясню так имеется усеченный конус верхний диамер40 нижний70 ,и отверстия 6 шт диаметром 3 по кругу с диаметром образующей 55 вот эти отверстия нужно просверлить перпендикулярно этому углу в конусе

Edited June 19, 2018 by Sergey1984

[DJ Astro 75]

Высота усеченного конуса?

[Sergey1984 4]

22 часа назад, DJ Astro сказал:

Высота усеченного конуса?

40мм.забыл извиняюсь 

[Steel_in 21]

В 6/26/2018 в 11:39, Sergey1984 сказал:

40мм.забыл извиняюсь 

Получилось? Тоже интересно посмотреть.

Edited July 17, 2018 by Steel_in

[Sergey1984 4]

В 7/17/2018 в 13:12, Steel_in сказал:

Получилось? Тоже интересно посмотреть.

Со стойки не получилось.в power mill да.так я и не понял как со стойки это сделать.трчнее не до конца понял

 

[DJ Astro 75]

Со стойки всё просто

[Sergey1984 4]

Надо попробовать

 

А можно всю программу целиком посмотреть

[DJ Astro 75]

На картинке и есть вся программа. В тех кадрах, что не видны - из кубика заготовки получается конус (чтобы в тестовой графике было наглядно понятно, что отверстия на конусе сверлятся правильно), эта часть Вам не нужна.

 

0  BEGIN PGM pgm MM 
1  BLK FORM 0.1 Z  X-40  Y-40  Z-40
2  BLK FORM 0.2  X+40  Y+40  Z+0
3  ;=========
4  TOOL CALL 1 Z S3000
5  ;=========
6  ;
7  PLANE RESET MOVE FMAX
8  ;
9  Q20 = 20
10 Q21 = 0
11 LBL 2
12 L  X-40  Y+0  Z+Q21 R0 F10000 M3
13 L  X-Q20 RL
14 CC  X+0  Y+0
15 CP IPA-360 DR-
16 L  X-40 R0
17 Q20 = Q20 + 0.375
18 Q21 = Q21 - 1
19 CALL LBL 2 REP39
20 ;
21 L  Z+100
22 M0
23 ;
24 ;
25 Q10 = 0
26 ;
27 LBL 1
28 PLANE SPATIAL SPA+0 SPB+69.4439 SPC+Q10 MOVE
29 L  X+28.3825  Y+0 R0 FMAX
30 L  Z+50 F5000
31 CYCL DEF 200 DRILLING ~
    Q200=+2    ;SET-UP CLEARANCE ~
    Q201=-5    ;DEPTH ~
    Q206=+500  ;FEED RATE FOR PLNGNG ~
    Q202=+5    ;PLUNGING DEPTH ~
    Q210=+0    ;DWELL TIME AT TOP ~
    Q203=+18.7266 ;SURFACE COORDINATE ~
    Q204=+30   ;2ND SET-UP CLEARANCE ~
    Q211=+0    ;DWELL TIME AT DEPTH
32 CYCL CALL M3
33 L  Z+50
34 ;
35 Q10 = Q10 + 60
36 CALL LBL 1 REP5
37 ;
38 END PGM pgm MM