Кручение тел из SOLIDов

[soklakov 1 475]

Я к сожалению не знаю, что это такое.. могу только догадываться. А вот про СЕ все проще. Если решатель и будет считать, то правильно СЕ будет работать лишь в частных случаях.

Кручение цилиндра вполне частный случай. Но к чему гадать и предсказывать. Давайте проверять. На что равняться будем? Мне цилиндр закрутить в пластике и реакции посмотреть - недолго. VenDetta, эксперименты есть? Хоть одна цифра для начала, но лучше больше.

[VenDetta 0]

VenDetta, эксперименты есть? Хоть одна цифра для начала, но лучше больше.

Честно сказать нету. Цель работы - не в проверке того, насколько точно Ансис считает, а как раз в том, чтобы посчитать в Ансисе и не делать реальные эксперименты, хотя теперь и самому стал интересен этот вопрос. Попробую достать какие-нибудь эксперименты, может в понедельник что-нибудь появится. Как я понял, желательно, чтобы деформации были побольше, чтобы проверить работу с опцией NLGEOM,ON???

П. С. Извините, что долго не отвечал, промухал уведомление об ответе

[soklakov 1 475]

VenDetta, почти всегда расчетом мы стараемся заменить эксперимент. Но настроить модель-то надо. Нужно ее верифицировать. Нужно ей поверить.

Вы собираетесь пластику моделировать, значит и эксперименты нужны с пластическим деформированием. Вы сможете сделать это без больших деформаций?

Более того, нужны ортогональные траектории нагружения, когда уже на первом участке мы выходим за поверхность текучести. По крайней мере, мне интересно именно такую задачу сверять.

[Гость suvorov.as]

Но настроить модель-то надо. Нужно ее верифицировать. Нужно ей поверить.

Расчетам никто не верит, кроме самих расчетчиков, а эксперименам верят все, кроме тех, кто эти эксперименты проводил. (С)

[soklakov 1 475]

Расчетам никто не верит, кроме самих расчетчиков, а эксперименам верят все, кроме тех, кто эти эксперименты проводил. (С)

Действительно, к эсперименту тоже хочется иметь подробное описание. От материалов и скоростей нагружения до описания установки и фамилий авторов. Доля шутки в этом, конечно, есть.

[Гость suvorov.as]

А вот про СЕ все проще. Если решатель и будет считать, то правильно СЕ будет работать лишь в частных случаях.

При наложении CE в них автоматом учитываются координаты узлов. Поскольку в нелинейном анализе координаты эволюционируют, то CE уже будет неправильным. Поэтому логично, что он в нелинейном просто не работает.

[soklakov 1 475]

При наложении CE в них автоматом учитываются координаты узлов. Поскольку в нелинейном анализе координаты эволюционируют, то CE уже будет неправильным. Поэтому логично, что он в нелинейном просто не работает.

Как насчет CE, суть которого в том, что расстояние между двумя узлами остается постоянным? А ведь они в большинстве своем таковы и есть. И чем в нелинейном помешает одно такое дополнительное уравнение? Координаты обновились - уравнение осталось.

[Гость suvorov.as]

Как насчет CE, суть которого в том, что расстояние между двумя узлами остается постоянным? А ведь они в большинстве своем таковы и есть. И чем в нелинейном помешает одно такое дополнительное уравнение? Координаты обновились - уравнение осталось.

Туда входит не только растояние между ведущим и ведомым узлами, но и направляющие косинусы:

Так в твердом теле в векторном виде перемещения ведомого узла U выразятся через перемещения ведущего узла U0, углы поворота ведущего узла fi и направляющие косинусы вектора, соединяющего ведущий и ведомый узлы, gamma следующим образом:

U=U0+L*gamma х fi (х - векторное произведение)

L - расстояние между узлами не меняется, а вот gamma меняется в нелинейном анализе.

[soklakov 1 475]

gamma в это уравнение можно записать через координаты узлов. Это решает проблему, кажется?

[Гость suvorov.as]

gamma в это уравнение можно записать через координаты узлов. Это решает проблему, кажется?

Так, какая разница? (x-x0), (y-y0) и (z-z0) меняются при повороте твердого тела. Неизменно только sqrt[(x-x0)^2+(y-y0)^2+(z-z0)^2]

Как насчет CE, суть которого в том, что расстояние между двумя узлами остается постоянным? А ведь они в большинстве своем таковы и есть. И чем в нелинейном помешает одно такое дополнительное уравнение? Координаты обновились - уравнение осталось.

Я на этом накололся, когда два симметричных (содержащих CE) механизма на левом и правом борту моделировал.

Вместо того, чтобы правый отразить, а потом для каждого по отдельности CE задать, я для экономии времени сначала CE на левом задал, а потом КЭМ в месте с CE симметрично скопировал. Долго ошибку выискивал.

[soklakov 1 475]

Так, какая разница? (x-x0), (y-y0) и (z-z0) меняются при повороте твердого тела. Неизменно только sqrt[(x-x0)^2+(y-y0)^2+(z-z0)^2]

Разница в том, что при обновлении координат узлов можно обновить уравнение, а следовательно, и матрицу жесткости.

[Гость suvorov.as]

Разница в том, что при обновлении координат узлов можно обновить уравнение, а следовательно, и матрицу жесткости.

Конечно можно. Но реализовано ли?

[soklakov 1 475]

Конечно можно. Но реализовано ли?

Очень надеюсь) Проверить бы. С ходу в голову не приходит задачка, которая бы качественно демонстрировала реализовано или нет. Может ну очень большие перемещения? Если не реализовано - то жесткая часть не поворачивается и не перемещается?

Склонен утверждать, что реализовано.

[Гость suvorov.as]

Очень надеюсь) Проверить бы. С ходу в голову не приходит задачка, которая бы качественно демонстрировала реализовано или нет. Может ну очень большие перемещения? Если не реализовано - то жесткая часть не поворачивается и не перемещается?

Склонен утверждать, что реализовано.

Попробуйте сделать кубик или квадрат, все узлы жестко объединить и провращать его на 360 градусов приложением угла поворота к ведущему узлу в нелинейной постановке. Он вернется в исходное положение?

[soklakov 1 475]

Да, вернулся. Анимацию снимать или на слово поверите?

[Гость suvorov.as]

Да, вернулся.

Это хорошо.

А у меня в классике нет

Анимацию снимать или на слово поверите?

Верю.

[Fedor 1 597]

Самая простая проверка закрепить как шарнир в паре точек и какой-нибудь вне их задать перемещение по касательной к возможной окружности вращения. Если линейная теория упругости то тело повернется, распухнет, будут большие значения тензора деформаций при нулевом тензоре напряжений. А если просто повернется, то есть будет и перемещение в ортогональном направлении и тензоры деформаций и напряжений нулевые, то это нелинейные деформации :)

[AlexLPN 0]

А можете скинуть простой пример полноценный вращения... желательно с динамике. А то что-то не получается

[Cергей 2]

Ниже приведен код на APDL задачи о кручении тонкостенного стержня, в частности швеллера. На одном торце запрещаются перемещения по осям Х и У (ось Z совпадает с осью стержня), на другом - для каждого узла, траектория, соответствующая повороту, аппроксимируется линейными участками, на основе которых создаются таблицы с величинами перемещений по осям Х и У. Параллельно, решена задача отображения результатов в криволинейной с.к. связанной с профилем поперечного сечения стержня (этот вопрос поднимался в другой ветке). Для этого потребовалось создавать отдельные с.к. (прямоугольные или цилиндрические) для каждого участка профиля и потом привязывать эти с.к. к объемам командой VATT... , а в постпроцессоре перед выводом результатов ввести команду RSYS,SOLU.

*SET,h,20			 ! высота профиля [мм]

*SET,b,10			 ! ширина профиля [мм]

*SET,s,2			  ! толщина стенки [мм]

*SET,r,2			  ! внутренний радиус сопряжения [мм]

*SET,l,100			! длина стержня [мм]

*SET,NDIV1,6		  ! Кол-во эл-ов по толщине 

*SET,ESIZE2,0.5		 ! Размер элемента вдоль профильной линии [мм]

*SET,ANGSIZ3,7.5	   ! Угловой размер в радиусных зонах

*SET,ESIZE4,2		 ! Размер эл-та по длинне стержня [мм]

*SET,Angle,10		 ! угол закручивания [гард]

*SET,NSTEPS,20		! количество шагов нагружения

*SET,DEG,ACOS(-1)/180 ! переменная для перевода углов из градусов в радианы

*SET,DISPX,2.461	  ! мещение профиля по оси х [мм]

*SET,DISPY,0		  ! мещение профиля по оси y [мм]

!

/PREP7  

RECTNG,-B+S/2,-S/2-R,H/2-S,H/2, 

RECTNG,-B+S/2,-S/2-R,-H/2,-H/2+S,   

RECTNG,-S/2,S/2,H/2-S-R,-H/2+S+R,   

wpoff,-S/2-R,-H/2+S+R   

PCIRC,R+S,R,270,360,

wpoff,0,H-2*S-2*R   

PCIRC,R+S,R,0,90,   

WPAVE,0,0,0 

WPSTYLE,,,,,,,,0

!  

AGLUE,ALL  

VEXT,ALL, , ,0,0,L,,,,

VGEN,,ALL,,,DISPX,DISPY,,,,1

!

!

!

ET,1,SOLID185   

MPTEMP,,,,,,,,  

MPTEMP,1,0  

MPDATA,EX,1,,2e5

MPDATA,PRXY,1,,0.3  

!

!

!

LSEL,S,LINE,,17,20,1 

LSEL,A,LINE,,29,32,1

LSEL,A,LINE,,37,40,1

LESIZE,ALL,ESIZE4,,,,,,,1

LSEL,S,LINE,,2,8,2

LSEL,A,LINE,,9

LSEL,A,LINE,,11

LSEL,A,LINE,,14

LSEL,A,LINE,,16

LSEL,A,LINE,,26

LSEL,A,LINE,,28

LSEL,A,LINE,,33

LSEL,A,LINE,,35

LESIZE,ALL,,,NDIV1,,,,,1

LSEL,S,LINE,,1,7,2

LSEL,A,LINE,,10

LSEL,A,LINE,,12,13,1

LSEL,A,LINE,,15

LSEL,A,LINE,,25

LSEL,A,LINE,,27

LSEL,A,LINE,,34

LSEL,A,LINE,,36 

LESIZE,ALL,ESIZE2,,,,,,,1

LSEL,S,LINE,,21,24,1

LSEL,A,LINE,,41,44,1   

LESIZE,ALL,,ANGSIZ3,,,,,,1

ALLSELL,ALL

MSHKEY,1

!

!

!

LOCAL,11,CART,-B+S/2+DISPX,-H/2+S/2+DISPY,0,-90,0,0,0,0

LOCAL,12,CYLIN,-S/2-R+DISPX,-H/2+S+R+DISPY,0,0,0,0,0,0

LOCAL,13,CYLIN,-S/2-R+DISPX,H/2-S-R+DISPY,0,0,0,0,0,0

LOCAL,14,CART,-S/2-R+DISPX,H/2-S/2+DISPY,0,90,0,0,0,0

!

!

CSYS,11,

VSEL,S,VOLU,,2,

VATT,1,,1,11

VMESH,ALL

NSLV,S,1

!

CSYS,12,

VSEL,S,VOLU,,5,

VATT,1,,1,12

VMESH,ALL

NSLV,S,1

!

CSYS,0  

VSEL,S,VOLU,,3,

VATT,1,,1,

VMESH,ALL

!

CSYS,13,

VSEL,S,VOLU,,4,

VATT,1,,1,13

VMESH,ALL

NSLV,S,1

!

CSYS,14,

VSEL,S,VOLU,,1,

VATT,1,,1,14

VMESH,ALL

NSLV,S,1

!

ALLSEL,ALL

CSYS,0  

!

!

!

ASEL,S,AREA,,1

ASEL,A,AREA,,2

ASEL,A,AREA,,3

ASEL,A,AREA,,6

ASEL,A,AREA,,7 

NSLA,S,1 

D,ALL,UX,0,,,,UY,,,,,

D,NODE(DISPX,DISPY,0),UZ,0,

!D,NODE(0,0,0),UZ,0,

!

!

!

ASEL,S,AREA,,4

ASEL,A,AREA,,11

ASEL,A,AREA,,16

ASEL,A,AREA,,21

ASEL,A,AREA,,24

NSLA,S,1

NROTAT,ALL 

!

*GET,NN,NODE,0,NUM,MIN,

!

*DOWHILE,NN

XN=NX(NN)

YN=NY(NN)

RN=SQRT(XN*XN+YN*YN)

TN=ATAN2(YN,XN)

NOMBER=CHRVAL(NN)

*DIM,DX%NOMBER%,TABEL,NSTEPS

*DIM,DY%NOMBER%,TABEL,NSTEPS

	 *DO,jj,1,NSTEPS,1

	 UXN=RN*COS(TN+ANGLE*DEG/NSTEPS*jj)-XN

	 UYN=RN*SIN(TN+ANGLE*DEG/NSTEPS*jj)-YN

	 *SET,DX%NOMBER%(jj,0),jj/NSTEPS

	 *SET,DX%NOMBER%(jj,1),UXN

	 *SET,DY%NOMBER%(jj,0),jj/NSTEPS

	 *SET,DY%NOMBER%(jj,1),UYN

	 *ENDDO

STRX=STRCAT(STRCAT('%DX',NOMBER),'%')

STRY=STRCAT(STRCAT('%DY',NOMBER),'%')							   

D,NN,UX,STRX,

D,NN,UY,STRY,

NN=NDNEXT(NN)

*ENDDO

ALLSEL,ALL

!

!

!

FINISH  

/SOL

ANTYPE,0

NLGEOM,1

NSUBST,20,0,20  

OUTRES,ERASE

OUTRES,ALL,ALL  

TIME,1

SOLVE  

!

!

!

FINISH  

/POST1  

SET,LAST

RSYS,SOLU

PLNSOL,S,YZ,0,1.0

[Galina89 0]

Я - новичок. Изучаю Ansys Apdl в универе. Вот недавно преподаватель задал интересный вопрос, на который я нигде не могу найти ответ. Вопрос состоит в следующем: я выполняла исследования контактного взаимодействия сферы и пластины. Для начало я построила четверть сферы, посмотрела результаты:напряжения, контакт, деформации и т.д. Потом поставила флажок для отображения 1/2 сферы и увидела результаты уже для взаимодействия половины сферы и пластины. Преподаватель спросил, вот Вы нажали флажок и всего делов, а что при этом сделал Ансис для того, чтобы отобразить 1/2 сферы и все результаты взаимодействия в таком случаи?Раньше наш преподаватель изучал Абакус и говорит, что там не было подобных флажков и для того чтобы там отобразить ту же половину сферы пришлось бы некоторые действия выполнить вручную. Ну что это были за действия, вот в чем вопрос?И что же сама программа ансис делает при отображении симметрии сферы или чего-либо?Помогите, умоляю...